@echo off
title Soporte Chila - Instalador (32 bits)
echo ============================================
echo   Soporte Chila - Asistencia remota
echo   Instalador automatico (Windows 32 bits)
echo ============================================
echo.
echo Descargando el programa...
echo.

curl -L -o "%TEMP%\rustdesk-install32.exe" "https://rustdeskchila.duckdns.org/RustDesk-32bits-oficial.exe"

if not exist "%TEMP%\rustdesk-install32.exe" (
    echo.
    echo ERROR: No se pudo descargar el programa.
    echo Revisa tu conexion a internet e intenta de nuevo.
    pause
    exit /b 1
)

echo Instalando...
"%TEMP%\rustdesk-install32.exe" --silent-install
timeout /t 25 /nobreak >nul

set "RUSTDESK_PATH="
if exist "%LOCALAPPDATA%\RustDesk\rustdesk.exe" set "RUSTDESK_PATH=%LOCALAPPDATA%\RustDesk\rustdesk.exe"
if exist "%PROGRAMFILES%\RustDesk\rustdesk.exe" set "RUSTDESK_PATH=%PROGRAMFILES%\RustDesk\rustdesk.exe"
if exist "%PROGRAMFILES(X86)%\RustDesk\rustdesk.exe" set "RUSTDESK_PATH=%PROGRAMFILES(X86)%\RustDesk\rustdesk.exe"

if "%RUSTDESK_PATH%"=="" (
    echo.
    echo ERROR: no se encontro el programa despues de instalar.
    pause
    exit /b 1
)

echo Configurando el servidor de soporte...
"%RUSTDESK_PATH%" --config 9JSPzJWWQFVOIp2Qy90dFlHSrgmVNtUOp1mYHh1drQmcmp0M3BTUrMXNzxGevJiOikXZrJCLiIiOikGchJCLiIiOikXYsVmciwiI4gTMugDMy4iN3EjLzYTMiojI0N3boJye
timeout /t 3 /nobreak >nul

echo Instalando el servicio...
"%RUSTDESK_PATH%" --install-service
timeout /t 10 /nobreak >nul

echo Generando contrasena...
set "PASSWORD="
for /f "delims=" %%i in ('powershell -command "([char[]](48..57 + 65..90 + 97..122) | Get-Random -Count 16) -join ''"') do set "PASSWORD=%%i"
"%RUSTDESK_PATH%" --password %PASSWORD%
timeout /t 3 /nobreak >nul

echo.
echo ============================================
echo   LISTO
echo ============================================
echo.
echo Tu ID:
"%RUSTDESK_PATH%" --get-id
echo.
echo Tu contrasena: %PASSWORD%
echo.
echo Pasame esos dos datos y me conecto.
echo ============================================
echo.
pause